<?php // This is just here so that the coloring would work. It does not exist in the ActionScript.

//////////////////////////////////////// 
// Vectrix - Sebastian Ahlman 2006 
// Main source code file. 
////////////////////////////////////////

// Set up the global variables.
speed = 6;
focalLength = 300;
framenumber = 0;
bonusCountdown = 200;
bonusPointsCollected = 0;

// Generate pseudo-random numbers
function randRange(min:Number, max:Number):Number
{
    var randomNum:Number = Math.floor(Math.random() * (max - min + 1)) + min;
    return randomNum;
}

// Function to create 3D-vectors.
CreateVector = function(x,y,z)
{
    var point = new Object();
    point.x = x;
    point.y = y;
    point.z = z;
    return point;
}

// Calculates the distance between two points in 3D space.
VectorLenght = function(point1, point2)
{
    vector = CreateVector(point1.x - point2.x, 
        point1.y - point2.y, point1.z - point2.z);
    
    temp = (vector.x * vector.x) + (vector.y * vector.y) +
        (vector.z * vector.z);
        
    return Math.sqrt(temp);
}

// Transform a point from 3D to 2D space.
TransformPoint = function(pointIn3D)
{
    var pointIn2D = new Object();
    var scaleRatio = focalLength/(focalLength + pointIn3D.z);
    pointIn2D.x = pointIn3D.x * scaleRatio;
    pointIn2D.y = pointIn3D.y * scaleRatio;
    return pointIn2D;
}

// Init. the scene.
this.createEmptyMovieClip("scene", 1);
scene._x = 300;
scene._y = 300;
scene.depth = 1;
scene.objects = new Array();
scene.bursterflames = new Array();

// Transforms a sprite (gives it the correct size
// and transforms it to 2D from a given 3D point)
TransformSprite = function(object, x, y, z)
{    
    var scaleRatio = focalLength/(focalLength + z);
    object._x = x * scaleRatio;
    object._y = y * scaleRatio;
    object._xscale = object._yscale = 100 * scaleRatio;
    object.swapDepths(Math.round(-z));
}

// Draw the asteroids and the particles on the screen.
drawAsteroid = function()
{
    if(this._name.substr(0, 5) == "light")
        this.z -= this.velocity * 0.5 + (framenumber * 0.03);
    else
        this.z -= this.velocity + (framenumber * 0.03);
    if(this.z <= -250)
    {
        if(this._name.substr(0, 5) == "light")
        {
            if(bonusCountdown == 200)
                break;
            else
                removeMovieClip(this);
        }
        this.x = randRange(-200, 200);
        this.y = randRange(-250, 250);
        this.velocity = randRange(5, 20);
        this.z = 550;
    }
    TransformSprite(this, this.x, this.y, this.z);
}

// Draw the burster flame particles.
drawBursterFlame = function()
{
    this.z -= 15 + (framenumber * 0.03);
    if(this.z <= -300) removeMovieClip(this);
    TransformSprite(this, this.x, this.y, this.z);
}

// Draw the ship onscreen and make it react to commands.
drawShip = function()
{
    if(Key.isDown(Key.LEFT)) key_left = true; else key_left = false;
    if(Key.isDown(Key.RIGHT)) key_right = true; else key_right = false;
    if(Key.isDown(Key.UP)) key_up = true; else key_up = false;
    if(Key.isDown(Key.DOWN)) key_down = true; else key_down = false;
    if(Key.isDown(Key.TAB)) key_tab = true; else key_tab = false;
    if(Key.isDown(Key.SHIFT)) key_shift = true; else key_shift = false;
    
    var screenPoints = new Array();
    for (var i=0; i < shipArray.length; i++)
    {
        var thisPoint = shipArray[i];        
        
        // React to controls
        if(key_left)
        {
            if(ship.loc.x > -200) thisPoint.x -= speed;
        }
        
        if(key_right)
        {
            if(ship.loc.x < 200) thisPoint.x += speed;
        }
        
        if(key_up)
        {
            if(ship.loc.y > -250) thisPoint.y -= speed;
        }
        
        if(key_down)
        {
            if(ship.loc.y < 250) thisPoint.y += speed;
        }
        
        if(key_tab)
        {
            if(ship.loc.z < 550) thisPoint.z += speed;
        }
        
        if(key_shift)
        {
            if(ship.loc.z > -50) thisPoint.z -= speed;
        }
        screenPoints[i] = TransformPoint(thisPoint);
    }
    
    this.clear();
    this.lineStyle(2,0xFFFFFF,100);
    
    // Draw the bottom of the ship
    this.moveTo(screenPoints[0].x, screenPoints[0].y);
    this.lineTo(screenPoints[1].x, screenPoints[1].y);
    this.lineTo(screenPoints[2].x, screenPoints[2].y);
    this.lineTo(screenPoints[3].x, screenPoints[3].y);
    this.lineTo(screenPoints[4].x, screenPoints[4].y);
    this.lineTo(screenPoints[2].x, screenPoints[2].y);
    this.moveTo(screenPoints[4].x, screenPoints[4].y);
    this.lineTo(screenPoints[5].x, screenPoints[5].y);
    this.lineTo(screenPoints[6].x, screenPoints[6].y);
    this.lineTo(screenPoints[7].x, screenPoints[7].y);
    this.lineTo(screenPoints[0].x, screenPoints[0].y);
    this.moveTo(screenPoints[1].x, screenPoints[1].y);
    this.lineTo(screenPoints[7].x, screenPoints[7].y);
    
    // Draw the upper part of the main body
    this.moveTo(screenPoints[1].x, screenPoints[1].y);
    this.lineTo(screenPoints[8].x, screenPoints[8].y);
    this.lineTo(screenPoints[9].x, screenPoints[9].y);
    this.lineTo(screenPoints[2].x, screenPoints[2].y);
    this.moveTo(screenPoints[9].x, screenPoints[9].y);
    this.lineTo(screenPoints[10].x, screenPoints[10].y);
    this.lineTo(screenPoints[5].x, screenPoints[5].y);
    this.moveTo(screenPoints[10].x, screenPoints[10].y);
    this.lineTo(screenPoints[11].x, screenPoints[11].y);
    this.lineTo(screenPoints[6].x, screenPoints[6].y);
    this.moveTo(screenPoints[11].x, screenPoints[11].y);
    this.lineTo(screenPoints[8].x, screenPoints[8].y);
    this.lineTo(screenPoints[7].x, screenPoints[7].y);
    this.moveTo(screenPoints[9].x, screenPoints[9].y);
    this.lineTo(screenPoints[4].x, screenPoints[4].y);
    this.moveTo(screenPoints[8].x, screenPoints[8].y);
    this.lineTo(screenPoints[0].x, screenPoints[0].y);
    this.moveTo(screenPoints[9].x, screenPoints[9].y);
    this.lineTo(screenPoints[3].x, screenPoints[3].y);
    
    // Nose
    this.moveTo(screenPoints[6].x, screenPoints[6].y);
    this.lineTo(screenPoints[12].x, screenPoints[12].y);
    this.lineTo(screenPoints[11].x, screenPoints[11].y);
    this.moveTo(screenPoints[5].x, screenPoints[5].y);
    this.lineTo(screenPoints[12].x, screenPoints[12].y);
    this.lineTo(screenPoints[10].x, screenPoints[10].y);
    
    // Tail
    this.moveTo(screenPoints[13].x, screenPoints[13].y);
    this.lineTo(screenPoints[14].x, screenPoints[14].y);
    this.lineTo(screenPoints[15].x, screenPoints[15].y);
    this.lineTo(screenPoints[16].x, screenPoints[16].y);
    this.lineTo(screenPoints[14].x, screenPoints[14].y);
    this.moveTo(screenPoints[16].x, screenPoints[16].y);
    this.lineTo(screenPoints[13].x, screenPoints[13].y);
}

// The points that make up the ship.
shipArray = [
    // Ship points
    CreateVector(-20, -35, -25),
    CreateVector(-10, -40, -20),
    CreateVector(10, -40, -20),
    CreateVector(20, -35, -25),
    CreateVector(10, -40, 20),
    CreateVector(10, -40, 30),
    CreateVector(-10, -40, 30),
    CreateVector(-10, -40, 20),
    CreateVector(-10, -50, -20),
    CreateVector(10, -50, -20),
    CreateVector(10, -50, 30),
    CreateVector(-10, -50, 30),
    CreateVector(0, -45, 50),
    CreateVector(-5, -50, -25),
    CreateVector(0, -60, -25),
    CreateVector(5, -50, -25),
    CreateVector(0, -50, 20),
    CreateVector(0, -50, 40) // Center of ship, reference point.
];

// Add some asteroids and particles to the scene.
for (i = 0; i < 5; i++)
{    
    scene.obj = scene.attachMovie("asteroid1", "asteroid1_"+i, scene.depth++);
    scene.obj.x = randRange(-200, 200);
    scene.obj.y = randRange(-250, 250);
    scene.obj.z = 550;
    scene.obj.velocity = randRange(5, 20);
    scene.obj.display = drawAsteroid;
    scene.objects.push(scene.obj);
}
for (i = 0; i < 3; i++)
{    
    scene.obj = scene.attachMovie("asteroid2", "asteroid2_"+i, scene.depth++);
    scene.obj.x = randRange(-200, 200);
    scene.obj.y = randRange(-250, 250);
    scene.obj.z = 550;
    scene.obj.velocity = randRange(5, 20);
    scene.obj.display = drawAsteroid;
    scene.objects.push(scene.obj);
}
for ( i= 0; i < 5; i++)
{    
    scene.obj = scene.attachMovie("asteroid3", "asteroid3_"+i, scene.depth++);
    scene.obj.x = randRange(-200, 200);
    scene.obj.y = randRange(-250, 250);
    scene.obj.z = 550;
    scene.obj.velocity = randRange(5, 20);
    scene.obj.display = drawAsteroid;
    scene.objects.push(scene.obj);
}
for ( i= 0; i < 50; i++)
{    
    scene.obj = scene.attachMovie("particle", "particle"+i, scene.depth++);
    scene.obj.x = randRange(-200, 200);
    scene.obj.y = randRange(-250, 250);
    scene.obj.z = randRange(-200, 550);
    scene.obj.velocity = randRange(5, 20);
    scene.obj.display = drawAsteroid;
    scene.objects.push(scene.obj);
}

// Create the ship and add it to the scene.
ship = scene.createEmptyMovieClip("ship", 1);
ship.loc = shipArray[17];
ship.display = drawShip;
scene.objects.push(ship);

RemoveLightningBall = function()
{
    this._visible = false
}

// Do the frame
doframe = function()
{
    framenumber++
    bonusCountdown --;
    if(bonusCountdown == 0)
    {
        bonusCountdown = 200;
        scene.ball = scene.attachMovie("lightning_ball", "lightning_ball"+framenumber, scene.depth++);
        scene.ball.x = randRange(-200, 200);
        scene.ball.y = randRange(-250, 250);
        scene.ball.z = 550;
        scene.ball.display = drawAsteroid;
        scene.ball.remove = RemoveLightningBall;
        scene.objects.push(scene.ball);
    }
    
    scene.bursterflame = scene.attachMovie("redparticle", "redparticle"+framenumber, scene.depth++);
    scene.bursterflame.x = ship.loc.x;
    scene.bursterflame.y = ship.loc.y;
    scene.bursterflame.z = ship.loc.z - 50;
    scene.bursterflame.display = drawBursterFlame;
    scene.bursterflames.push(scene.bursterflame);
    
    for(i = 0; i < scene.objects.length; i++)
    {
        currentObject = scene.objects[i];
        currentObject.display();
        if(currentObject._name.substr(0, 8) == "asteroid")
        {
            // Check for collisions with the asteroids.
            if(VectorLenght(CreateVector(ship.loc.x, ship.loc.y, 
                ship.loc.z), CreateVector(currentObject.x,
                currentObject.y, currentObject.z)) < 40)
            {
                finalBonusPoints = "You got " + bonusPointsCollected + " bonus points";
                finalscore = "Your final score: " + (framenumber + bonusPointsCollected);
                if((framenumber + bonusPointsCollected) < 50)
                    result = "Were you sleeping?";
                else if((framenumber + bonusPointsCollected) < 200)
                    result = "Come on! You can do better!";
                else if((framenumber + bonusPointsCollected) < 500)
                    result = "Well, not all that bad...";
                else if((framenumber + bonusPointsCollected) < 1000)
                    result = "That was actually pretty good!";
                else if((framenumber + bonusPointsCollected) < 1500)
                    result = "You are really good at this!";
                else if((framenumber + bonusPointsCollected) < 2000)
                    result = "You just keep amazing me...";
                else
                    result = "Did you find some way to cheat?";
                backgroundSound.stop();
                crashSound = new Sound(this);
                crashSound.attachSound("crashmusic");
                crashSound.start();
                gotoAndStop(3);
                for(j = 0; j < scene.objects.length; j++)
                    scene.removeMovieClip(scene.objects.pop());
                scene.onEnterFrame = null;
            }
        }
        else if(currentObject._name.substr(0, 5) == "light")
        {
            if(VectorLenght(CreateVector(ship.loc.x, ship.loc.y, 
                ship.loc.z), CreateVector(currentObject.x,
                currentObject.y, currentObject.z)) < 40)
            {
                currentObject.remove();
                scene.objects.splice(i, 1);
                bonusPointsCollected += 100;
                ballSound = new Sound(this);
                ballSound.attachSound("lightning_ball_sound");
                ballSound.start();
            }
        }
    }
    for(i = 0; i < scene.bursterflames.length; i++)
    {
        scene.bursterflames[i].display();
    }
}

scene.onEnterFrame = doframe;
stop();

// This line is also needed to make the coloring work.
?>